# Copyright (c) 2024, The Monero Project
#
# All rights reserved.
#
# Redistribution and use in source and binary forms, with or without modification, are
# permitted provided that the following conditions are met:
#
# 1. Redistributions of source code must retain the above copyright notice, this list of
#    conditions and the following disclaimer.
#
# 2. Redistributions in binary form must reproduce the above copyright notice, this list
#    of conditions and the following disclaimer in the documentation and/or other
#    materials provided with the distribution.
#
# 3. Neither the name of the copyright holder nor the names of its contributors may be
#    used to endorse or promote products derived from this software without specific
#    prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND ANY
# EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES OF
# MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL
# THE COPYRIGHT HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
# PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
# INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
# STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF
# THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.

set(fcmp_pp_sources
  curve_trees.cpp
  fcmp_pp_crypto.cpp
  fcmp_pp_types.cpp
  prove.cpp
  tower_cycle.cpp
  tree_cache.cpp)

monero_find_all_headers(fcmp_pp_headers "${CMAKE_CURRENT_SOURCE_DIR}")

add_subdirectory(fcmp_pp_rust)

monero_add_library_with_deps(
  NAME fcmp_pp
  DEPENDS fcmp_pp_rust
  SOURCES
    ${fcmp_pp_sources}
    ${fcmp_pp_headers})

if(WIN32)
  set(EXTRA_RUST_LIBRARIES ws2_32 ntdll userenv)
else()
  set(EXTRA_RUST_LIBRARIES )
endif()

target_link_libraries(fcmp_pp
  PUBLIC
    cncrypto
    common
    epee
  PRIVATE
    ${Boost_SERIALIZATION_LIBRARY}
    ${CMAKE_CURRENT_BINARY_DIR}/fcmp_pp_rust/libfcmp_pp_rust.a
    ${EXTRA_LIBRARIES}
    ${EXTRA_RUST_LIBRARIES})

# Try compiling C file ffi_api_c_compat.c which includes fcmp++.h, and throw an error if C compilation fails
try_compile(FFI_API_C_COMPAT_RES
  "${CMAKE_CURRENT_BINARY_DIR}/fcmp_ffi_c"
  "${CMAKE_CURRENT_SOURCE_DIR}/ffi_api_c_compat.c"
  CMAKE_FLAGS -DCMAKE_C_STANDARD=11
  COMPILE_DEFINITIONS -I"${CMAKE_CURRENT_SOURCE_DIR}/fcmp_pp_rust"
  OUTPUT_VARIABLE FFI_API_C_COMPAT_OUTPUT)
if(NOT FFI_API_C_COMPAT_RES)
  message(SEND_ERROR "Error compiling ffi_api_c_compat.c: ${FFI_API_C_COMPAT_OUTPUT}")
  message(FATAL_ERROR "The FCMP++ FFI API header 'fcmp++.h' has broken compatibility with C")
endif()
